Использование ТКС АПИ для заполнения BOM в CAD-ах

Public Sub ThirdStep_1()

Dim TCS As CSDN.TCS
Dim App As CSDN.Tcs_Application

'Создадим объект ТКС АПИ

Set TCS = CreateObject("CSDN.TCS")

'Создадим экземляр приложения (сеанс). Внимание ! создание повторного сеанса не допустимо!


Set App = TCS.Login 'вызывает стандартное окно аутентификации пользователя

'Set App = TCS.LoginEx("Администратор", "0")  ' Если вы сами пишите диалог ввода пользователя и пароля или просто его знаете

'Set App = TCS.LoginCurrent ' если вы хотите использовать сеанс уже запущенного ТКС


'Выберем классы испольдзуемые в спецификации
App.NmkClasses.ClassView = 1

'Просим пользователя выбрать один класс, номенклатура которого его интересует.
'На практике конструктора вполне возможно уже будут знать заранее используемые классы
'так что вы можете заложиться в программе сразу на конкретные классы, или
'ввести сразу команды по выбору материала, или детали
'в этом случае диалог выбора класса конечно не нужен,
'а вместо него появится вот такая строчка кода
' If App.NMkClasses.Locate( "NOTE", "Предопределенное обозначение класса", 0 ) Then

If App.NmkClasses.RunModuleForSelect("Выберите класс номенклатуру которого хотите добавить", False) > 0 Then
   Dim Nmks As CSDN.Nomenclatures
   Dim I As Integer
   Dim NMkRes As String
     
   
   Set Nmks = App.Nomenclatures(App.NmkClasses.Properties("ID").AsInteger)
   
   'Здесь указан более сложный вариант для выбора нескольких позиций
   'в случае если надо выбрать одну номенклатуру нужно замениить код на
   'If Nmks.RunModuleForSelect("Выберите номенклатурные позиции", False) > 0 Then
   'ну и дальше просто сразу взять нужные вам значения
   If Nmks.RunModuleForSelect("Выберите номенклатурные позиции", True) > 0 Then
     
      For I = 0 To Nmks.SelectedRowsCount - 1
        'Для простоты просто копируем все необходимые свойства
        'реально имеено здесь вы получаете данные и сохраняете там где вам нужно
        
        If Nmks.GotoSelectedRow(I) Then
        
           NMkRes = NMkRes + Nmks.Properties("NOTE").AsString + " - " + Nmks.Properties("NAME").AsString + _
                            ": Идентификатор - " + Nmks.Properties("ID").AsString + " ; "
        End If
              
        
      Next I
      
    'освободим объект номенклатурый справочник
    Set Nmks = Nothing
    
    'Покажем выбранные результаты
    MsgBox NMkRes
      
   End If
   
   
Else: MsgBox "Класс не выбран"
End If

Set App = Nothing
Set TCS = Nothing


End Sub

Public Sub ThirdStep_2()

Dim TCS As CSDN.TCS
Dim App As CSDN.Tcs_Application

'Создадим объект ТКС АПИ

Set TCS = CreateObject("CSDN.TCS")

'Создадим экземляр приложения (сеанс). Внимание ! создание повторного сеанса не допустимо!


Set App = TCS.Login 'вызывает стандартное окно аутентификации пользователя

'Set App = TCS.LoginEx("Администратор", "0")  ' Если вы сами пишите диалог ввода пользователя и пароля или просто его знаете

'Set App = TCS.LoginCurrent ' если вы хотите использовать сеанс уже запущенного ТКС


'Ищем класс сборочных единиц
If App.NmkClasses.Locate("NOTE", "СБ", 0) Then

   Dim Nmks As CSDN.Nomenclatures
   Dim I As Integer
   Dim NMkRes As String
   Dim Prop As CSDN.IProp
   Dim Childs As CSDN.IChildModules
   Dim Spec As CSDN.IGModule
   
   Set Nmks = App.Nomenclatures(App.NmkClasses.Properties("ID").AsInteger)
   
   'Опять таки в реальной жизни вам будет известна номенклатура на которую ведется
   'спецификация и вволне возможно даже ее идентификатор.
   'Тогда вместо выбора появится строчка
   ' If Nmks.Locate( "NOTE", "Обозначение номенклатурной позиции", 0 ) Then
   On Error GoTo Err1
   If Nmks.RunModuleForSelect("Выберите номенклатуру на которую выведете спецификацию", False) > 0 Then
     
     
     'Получим спецификацию на нашу номенклатуру
     Set Childs = Nmks.ChildModules
     Set Prop = Childs.ModuleByName("Specification")
     
     'If Prop Is Nothing Then Set Prop = Nmks.ChildModules.ModuleItems(10)
     
     Set Spec = Prop.Value
   
     'Покажем спецификацию пользователю о попросим его выбрать
     'номенклатуру сразу  из спецификации
     'а если ее нет, то добавить ее в спецификацию ТКС, а потом выбрать
     'таким образом сразху ведется  спецификация и в ТКС и в вашей программе.
     'и даже необязательно делать импорт спецификации в последующем
     'хотя функции их сравнения наверное не помешают
     'В будущем разумеется вы сможете вести спецификацию даже без окна ТКС
     'хотя это потребует написания немалого кода с вашей стороны.
     If Spec.RunModuleForSelect("выберите номенклатуру из спецификации :" + _
                                 Nmks.Properties("NOTE").AsString + " - " + _
                                 Nmks.Properties("NAME").AsString, True) Then
                                 
     
       For I = 0 To Spec.SelectedRowsCount - 1
         If Spec.GotoSelectedRow(I) Then
           NMkRes = NMkRes + Spec.Properties("NMK_NOTE").AsString + " - " + _
                             Spec.Properties("NMK_NAME").AsString + ": Идентификатор -" + _
                             Spec.Properties("NMK_ID").AsString + " ; "
          
         End If
        
       Next I
       
       'Покажем выбранные результаты
       MsgBox NMkRes
       
     End If
    
     
   End If
   
Err1:
   
   Set Prop = Nothing
   Set Childs = Nothing
   Set Spec = Nothing
   Set Nmks = Nothing
  
  
 
 Else: MsgBox "Отсутвует класс СБ"
End If

Set App = Nothing
Set TCS = Nothing


End Sub